当前位置: 洪哥笔记 > ASP > asp调用CDONTS发邮件

 

asp调用CDONTS发邮件


关键词

asp调用CDONTS发邮件

摘要

<p>Windows2000已经包含<strong>CDONTS</strong>.dll邮件组件。<br /> Windows xp, Windows 2003 默认没有附带CDONTS.DLL,必须手动安装,你可以从Windows 2000的system32中得到该文件,<br /> 安装方法:<br /> Step1: 将该文件拷贝至 %SystemRoot%\System32 下;<br /> Step2: 开始 -> 运行 -> Regsvr32 cdonts.dll;<br /> Step3: 确认<br /><br />附:一个<strong>ASP</strong>调用<strong>CDONTS发邮件</strong>的示例:<br /><br /><%<br /> &#160; &#160;Dim oMail, sBody, sCc, sBCc, sTo, sFrom, sSubject, sContentBase<br /></p>

Windows2000已经包含CDONTS.dll邮件组件。
Windows xp, Windows 2003 默认没有附带CDONTS.DLL,必须手动安装,你可以从Windows 2000的system32中得到该文件,
安装方法:
Step1: 将该文件拷贝至 %SystemRoot%\System32 下;
Step2: 开始 -> 运行 -> Regsvr32 cdonts.dll;
Step3: 确认


附:一个ASP调用CDONTS发邮件的示例:

<%
   Dim oMail, sBody, sCc, sBCc, sTo, sFrom, sSubject, sContentBase
   
   '//构造正文
   sBody = "<HTML>" & _
       "<HEAD>" & _
       "<TITLE>用CDONTS发送邮件</TITLE>" & _
       "<BODY>" & _
       "WELCOME TO OUR COCOON sTudio.<BR>" & _
       "<IMG SRC='http://www.ccopus.com/img/cocoon.gif'><p>" & _
       "这幅图片来自AttachURL所指定的附件<IMG SRC=ha.jpg>" & _
       "</BODY>" & _
       "</HEAD>" & _
       "</HTML>"
   sSubject = "用CDONTS发送邮件"
   sFrom = "sunrise@citiz.net"
   sTo = "sunrise_chen@citiz.net"
   sCc = "sunrise@jicang.com"
   sBCc = "sunrise@citiz.net"
   sContentBase = "http://www.ccopus.com/"
   Set oMail = Server.CreateObject("CDONTS.NewMail")

   '//以URL形式添加附件,在附件列表中不可见,可以在正文中访问
   oMail.AttachURL Server.MapPath("ha.jpg"), "ha.jpg"
   
   '//以文件形式添加附件,在附件列表中可见,不可在正问中直接访问
   oMail.AttachFile Server.MapPath("mail.asp"), "SMTPmail.txt"
   
   '//指定mail正文的基地址,不能于AttachURL同时使用,否则,AttachURL附带的附件文件名将不正确。
   'oMail.ContentBase = sContentBase
   
   '//指定邮件主题
   oMail.Subject = sSubject
   
   '//指定发件人
   oMail.From = sFrom
   
   '//指定收件人,可写多个收件人,用逗号隔开
   oMail.To = sTo
   
   '//抄送给其他人,可以指定多个,用逗号隔开
   oMail.Cc = sCc
   
   '//暗抄给其他人,可以指定多个,用逗号隔开
   oMail.BCc = sBCc

   '//指定邮件正文    
   oMail.Body = sBody
   
   '//指定邮件为HTML格式    '//0: The NewMail object is to be in MIME format.    '//1: The NewMail object is to be in uninterrupted plain text (default value).
   oMail.MailFormat = 0
   
   '//指定邮件为MINE格式
   '//0: The Body property is to include Hypertext Markup Language (HTML).    '//1: The Body property is to be exclusively in plain text (default value).
   oMail.BodyFormat = 0
   
   
   '//指定邮件级别 0: 普通 1:机密 2:绝密
   oMail.Importance=0
   
   '//发送邮件
   oMail.Send

   Set oMail = Nothing
%>

 

要饭二维码

洪哥写文章很苦逼,如果本文对您略有帮助,可以扫描下方二维码支持洪哥!金额随意,先行谢过!大家的支持是我前进的动力!

文章的版权

本文属于“洪哥笔记”原创文章,转载请注明来源地址:asp调用CDONTS发邮件:http://www.splaybow.com/post/cdonts17065929122007.html

如果您在服务器运维、网络管理、网站或系统开发过程有需要提供收费服务,请加QQ:115085382!十年运维经验,帮您省钱、让您放心!
亲,如果有需要,先存起来,方便以后再看啊!加入收藏夹的话,按Ctrl+D

« asp生成文本文件 曾经捕获的一个木马程序 »

相关文章: